// These macros open all the files in a folder and place them in a stack
// Two dialog boxes are displayed. Select the source folder in the
// first and the destination folder in the second.

//
// This macro assumes that the files are named in some kind of logical order
// the images are placed in a first in / first out stack with image #1
// on top followed by image #2 and so on
//
// gma - 28 mar 05
//

  macro "Batch Convert TIFFs to Stack" { convert("tiff"); }

  function convert(format) {
      requires("1.33s");

      // prompt user for source directory
      dir1 = getDirectory("Choose Source Directory ");

      // prompt user for dsetination directory
      dir2 = getDirectory("Choose Destination Directory ");

      // read in file listing from source directory
      list = getFileList(dir1);

      // call the sort function and sort the list
      sort(list);

      // loop over the files in the source directory
      setBatchMode(true);
      for (i=0; i<list.length; i++) {
          showProgress(i+1, list.length);
          open(dir1+list[i]);

          //////
          ////
          // do some thing to *each* file here
          ////
          //////
      }

      // place all open file in a stack
      run("Convert Images to Stack");

      // save the stack
      saveAs(format, dir2+"stack.tif");

      //close the file
      close();
  }

  // wrapper function for quicksort
  function sort(a) {quickSort(a, 0, lengthOf(a)-1);}

  // quicksort function
  function quickSort(a, from, to) {
      i = from; j = to;
      center = a[(from+to)/2];
      do {
          while (i<to && center>a[i]) i++;
          while (j>from && center<a[j]) j--;
          if (i<j) {temp=a[i]; a[i]=a[j]; a[j]=temp;}
          if (i<=j) {i++; j--;}
      } while(i<=j);
      if (from<j) quickSort(a, from, j);
      if (i<to) quickSort(a, i, to);
  }